//**************************************************************************
// Simulation de la trajectoire du plan d'oscillation du pendule de Foucault
// Dominique Lefebvre  Octobre 2012
// TangenteX.com
//**************************************************************************

// Définition des paramètres généraux
DeuxPi = 6.28;
DureeJour = 24*3600;         // durée du jour en USI

// Définition des paramètres du pendule
TPendule = 3600;             // Période du pendule en USI

// Saisie de la latitude
lat = input("Latitude du lieu (en degres): ");
lat = lat*DeuxPi/360;       // latitude en rad

// Paramètres dérivés
Omega0 = DeuxPi/TPendule;
OmegaT = DeuxPi/DureeJour;   // vitesse angulaire de la Terre en USI
OMEGA = OmegaT*sin(lat);
if lat > 0
  TPlanOsc = DeuxPi/OMEGA;   // période du plan d'oscillation verticale en USI
else
  TPlanOsc = 0.0;           // cas du calcul à l'équateur
end;

// conditions initiales
t0 = 0;
x0 = 1.0;
y0 = 0;

// Paramètres de simulation
PasTemp = DureeJour/1000;
t = t0:PasTemp:DureeJour;

// Calcul 
x = x0*cos(Omega0*t).*cos(OMEGA*t);
y = -x0*cos(Omega0*t).*sin(OMEGA*t);

// Tracé
n = length(t); 
plot2d(x(1:n),y(1:n),style = 2);

// Libellés
xtitle("Pendule de Foucault - Rotation du plan d''oscillation");
lib1 = cat(2,'Latitude = ', string(lat*360/DeuxPi), 'degrés');
xstring(-0.95,0.90,lib1);
lib2 =  cat(2,'Période  = ', string(TPlanOsc/3600), 'heures');
xstring(0.35, 0.90,lib2);