Retour

Simuler l'effet tunnel

Qu'est-ce que l'effet tunnel

Nous avons abordé sur une autre page de ce site l'équation de Schrödinger, sa forme et ses solutions. Comme vous le savez, cette équation implique qu'une particule soit définie par sa fonction d'onde. En d'autres termes, une particule peut être traitée comme une onde (attention, je n'ai pas écris que c'était une onde!). Dans le cours d'optique ondulatoire, on apprend qu'une onde qui rencontre un dioptre se comporte d'une façon particulière : une partie de l'onde est transmise à travers le dioptre, l'autre partie est réfléchie. Cette particularité est-elle retrouvée dans le comportement d'une particule vu par la physique quantique?

Et bien oui! Considérons par exemple un électron qui rencontre une barrière de potentiel positive. En mécanique classique, soit l'électron a une énergie plus grande que celle du potentiel de la barrière et il passe, soit ce n'est pas le cas et il est repoussé. En mécanique quantique, on retrouve le comportement d'une onde. Il est possible, avec une probabilité plus ou moins faible, que l'électron passe, même si son énergie est plus faible que le potentiel de la barrière. C'est l'analogue de la transmission d'une onde à travers un dioptre et on appelle ceci l'effet tunnel.

Il faut dire que c'est une conséquence assez troublante de la mécanique quantique et plus précisément de l'équation de Schrödinger, mais qui est vérifiée tous les jours!

Ses conséquences et applications sont nombreuses:

Voyons comment appréhender simplement, et il faut le dire de façon plutôt simpliste, cet effet par une simulation...

Comment simuler l'effet tunnel 1D

Pour simuler l'effet tunnel, nous allons nous placer dans la situation expérimentale où un faisceau d'électrons homogène frappe une barrière de potentiel de hauteur V0 et de largeur l. L'énergie des électrons incidents sera notée En, et bien sur En < V0, sinon, il n'y a plus de jeu! Nous considérerons que les électrons ne sont pas relativistes, histoire de pouvoir utiliser Schrödinger!

Classiquement, je définis un repère xOV, la marche gauche de la barrière de potentiel étant centrée sur l'origine du repère, c'est plus facile pour les calculs. Toujours aussi classiquement, je décide que le faisceau d'électrons proviendra de la gauche du repère, de x = - INF.

Nous allons découper l'espace 1D en trois régions et poser l'équation de la fonction d'onde solution de Schrödinger, propre à chaque région, comme vous avez appris à le faire en cours:

Dans ces équations :

Je m'intéresse aussi au coefficient de transmission T, c'est à dire la proportion d'électrons qui ont traversé la barrière de potentiel par effet tunnel. Il est obtenu par un long calcul (voir votre cours) et dans notre cas, on a T = |C|2. On laissera le programme le calculer! Il sera intéressant de faire varier la largeur de la barrière l, pour étudier l'influence de l sur T....

Voilà, le cadre est fixé, nous avons toutes les informations nécessaires pour écrire un petit programme qui va nous tracer l'évolution de la fonction d'onde avant la barrière, dans la barrière et après la barrière, puis nous calculer T.

Le programme

Le programme de simulation est écrit en Maple, ce qui simplifie grandement l'écriture par rapport à un programme C!
La programmation Maple n'appelle pratiquement pas de commentaires, tant elle est conforme aux données de spécification indiquées ci-dessus. Si, peut être à signaler les conditions de continuité de la fonction d'onde et de sa dérivée dans l'appel de solve(). Ou encore l'usage de la fonction piecewise pour définir la barrière de potentiel, une fonction continue par morceaux.
Le source est téléchargeable ici.

#*************************************************************************

# programme de simulation de l'effet tunnel sur une barrière de potentiel

# rectangulaire

# Dominique Lefebvre octobre 2012

# www.tangenteX.com

#*************************************************************************

# initialisation des paramètres de la simulation

me := 9.1e-31:    # masse de l'électron (USI)

V0 := 10*1.6e-19: # hauteur de la barrière de potentiel (10 eV en USI)

l := 1.8e-10:     # largeur de la barrière de potentiel (USI)

h := 1.055e-34:   # hbarre

# définition de l'énergie de l'électron et de sa fréquence

En := 6*1.6e-19:  # énergie de l'électron incident (6 eV)

w := En/h:        # fréquence de l'onde associée à l'électron

# définition des coefficients des exponentielles

k1:=sqrt(2*me*En)/h:

k2:=sqrt(2*me*(V0-En))/h:

# calcul des exponentielles

psi1 := x -> exp(I*k1*x) + B*exp(-I*k1*x):

psi2 := x -> F*exp(k2*x) + G*exp(-k2*x):

psi3 := x -> C*exp(I*k1*x):

# résolution de l'équation avec les conditions initiales définies

sol := solve({psi1(0) = psi2(0), psi2(l) = psi3(l), D(psi1)(0) = D(psi2)(0), D(psi2)(l)= D(psi3)(l)}, {B, C, F, G}):

assign(sol):

# calcul des fonctions

tpsi1(x,t) := psi1(x)*exp(-I*w*t):

tpsi2(x,t) := psi2(x)*exp(-I*w*t):

tpsi3(x,t) := psi3(x)*exp(-I*w*t):

#définition de la fonction "barrière de potentiel"

barriere := piecewise(0 < x and x < l,V0/En, x < 0,0,l < x,0):

# définition des courbes graphiques

with(plots):

c1 := animate(Re(tpsi1(x,t)), x=-4*l..0, t=0..2*Pi/w):

c2 := animate(Re(tpsi2(x,t)), x=0..l, t=0..2*Pi/w):

c3 := animate(Re(tpsi3(x,t)), x=l..l+4*l, t=0..2*Pi/w):

# définition de la barrière

cbarriere := plot(barriere, x=-4*l..4*l, color=blue, thickness=2):

# tracé des courbes et de la barrière

display([c1, c2, c3, cbarriere]);

# calcul du coefficient de transmission T

T := C*conjugate(C):

T := evalc(T):

T : simplify(T);

Quelques instructions pour l'utiliser:

Maintenant, c'est à vous!

Les résultats

Voici l'allure de la fonction d'onde pour une largeur de barrière de 1.8*10-10 m. On distingue bien le comportement de l'onde incidente avant, pendant et après le passage de la barrière. En mécanique classique, il n'y aurait aucun signal à droite de la barrière. En quantique, le signal est affaibli mais existe toujours!

Effet tunnel sur une barrière de potentiel

La valeur du coefficient de transmission T calculée à partir des paramètres de la simulation est de T = 0.092 pour une largeur de barrière de 1.8*10-10 m.

Pour une largeur de barrière de 3.6*10-10 m, le coefficient de transmission tombe à 0.002, soit une atténuation d'un ordre de grandeur pour un doublement de la largeur,  et la fonction d'onde devient:

Effet tunnel sur une barrière de potentiel

Vous noterez la forte influence de la largeur de la barrière sur la proportion d'électrons qui passeront la barrière...


Contenu et design par Dominique Lefebvre - www.tangenteX.com octobre 2012 -- Vous pouvez me joindre par mail ou sur PhysiqueX

Licence Creative Commons

Cette œuvre est mise à disposition selon les termes de la Licence Creative Commons Attribution - Pas d’Utilisation Commerciale - Pas de Modification 3.0 France .